split: /* (string, sep, stem[, limit]) */
  $sep = escape(arg(2), "'", "'")
  $l = cequ(arg(4, "E"), arg(4), -1)
  if $l = 1 then do
    $w = arg(1)
    $s = ""
  end
  else interpret "parse value arg(1) with $w'"$sep"'$s"
  $i = 1
  interpret arg(3)".$i=$w"
  do while $s <> ""
    $l = $l - 1
    if $l = 1 then do
      $w = $s
      $s = ""
    end
    else interpret "parse var $s $w'"$sep"'$s"
    $i = $i + 1
    interpret arg(3)".$i=$w"
  end
  interpret arg(3)".0=$i"
return 1

escape: procedure /* (string, chars, escape) */
  s = arg(1)
  sc = cequ(arg(2, "E"), arg(2), "'""\<>")
  ec = cequ(arg(3, "E"), arg(3), "\")
  r = ""
  l = length(s)
  do i = 1 to l
     c = substr(s, i, 1)
     if index(sc, c) > 0 then r = r !! ec
     r = r !! c
  end
return r

lCase: procedure /* (string) */
  s = arg(1)
  ccal = c2d("a")
  cczl = c2d("z")
  ccAU = c2d("A")
  ccZU = c2d("Z")
  ccd = ccal - ccAU
  r = ""
  do i = 1 to length(s)
    c = substr(s, i, 1)
    cc = c2d(c)
    if cc >= ccAU & cc <= ccZU then cc = cc + ccd
    r = r !! d2c(cc)
  end
return r

uCase: procedure /* (string) */
  s = arg(1)
  parse upper var s s
return s

formatArg:
  if datatype(arg(1)) = "NUM" then return arg(1)
return '"'escape(arg(1), '"', '"')'"'

replace: procedure /* (string, find, replace) */
  parse arg s, f, r
  fl = length(f)
  x = ""
  lp = 1
  p = index(s, f)
  do while p > 0
    x = x !! substr(s, lp, p - lp) !! r
    lp = p + fl
    p = index(s, f, lp)
  end
return x !! substr(s, lp)

startsWith: procedure /* (string, s) */
return left(arg(1), length(arg(2))) = arg(2)